// Raindrops
//
// based on an idea by Hugo Elias
// (http://freespace.virgin.net/hugo.elias/graphics/x_water.htm)
//
// Implementation with Processing
// and smoothing by Mario Klingemann
// http://incubator.quasimondo.com
//
// Reuse of this code is permitted
// as long as this copyright notice
// is included.

int[] map1;
int[] map2;
int[] mapIn;
int[] mapOut;
int asize;
boolean step;
int rainfall;
boolean show;
int strength=8000;

BImage a;
void setup(){
  a= loadImage("floor.jpg");
  size(a.width,a.height);
  asize=width*height;
  rainfall=1;
  step=false;
  initmaps();
  show=false;
}

void loop(){
  if (!step){
    mapIn=map1;
    mapOut=map2;
  } else {
    mapOut=map1;
    mapIn=map2;
  }
  rain();
  updatemap();
  fastblur();
  if (show){
    showmap();
  } else {
    rendermap();
  }
  step=!step;
}

void keyPressed(){
  show=true;
}

void keyReleased(){
  show=false;
}

void rain(){
  mapIn[int(random(asize-1))]+=int(random(-strength,strength));
}

void initmaps(){
  map1=new int[asize];
  map2=new int[asize];
}

void updatemap(){
  int x,y,yw,i;
  for (y=1;y<height-1;y++){
    yw=y*width;
    for (x=1;x<width-1;x++){
      i=x+yw;
      mapOut[i] = ((mapIn[i-1] + mapIn[i+1] + mapIn[i+width] + mapIn[i-width])>>1) - mapOut[i];
      mapOut[i] -=mapOut[i]>>8;
    }
  }
}

void showmap(){
  int p;
  for (int i=0;i<asize;i++){
    p=mapOut[i]+128;
    if (p<0) p=0;
    if (p>255) p=255;
    pixels[i]=0xff000000 | p<<16 | p<<8 | p;
  }

}

void rendermap(){
  int o,p,i,x,y,xo,yo,r,g,b,shade;
  int[] pix=a.pixels;
  i=0;

  for (y=0;y<height;y++){
    for (x=0;x<width;x++){
      if (x==0){
        xo=mapOut[i]-mapOut[i+1];
      } else if (x==width-1){
        xo=mapOut[i-1]-mapOut[i];
      }else{
        xo=mapOut[i-1]-mapOut[i+1];
      }
      if (y==0){
        yo=mapOut[i]-mapOut[i+width];
      } else if (y==height-1){
        yo=mapOut[i-width]-mapOut[i];
      }else{
        yo=mapOut[i-width]-mapOut[i+width];
      }
      //shade=(xo+yo)>>2;
      xo+=x;
      yo+=y;
      while (xo<0) xo+=width;
      while (yo<0) yo+=height;
      while (xo>=width) xo-=width;
      while (yo>=height) yo-=height;

      /*
      // Additional Shading
      p=pix[xo+yo*width];
      r=(p&0xff0000)>>16;
      g=(p&0x00ff00)>>8;
      b=(p&0x0000ff);
      r+=shade;
      g+=shade;
      b+=shade;
      if (r<0) r=0;
      if (r>255) r=255;
      if (g<0) g=0;
      if (g>255) g=255;
      if (b<0) b=0;
      if (b>255) b=255;
      pixels[i++]=0xff000000 | r<<16 | g<<8 | b;
      */
      pixels[i++]=pix[xo+yo*width];
    }
  }

}

void fastblur(){
  int w=width;
  int h=height;
  int wm=w-1;
  int hm=h-1;
  int wh=w*h;
  int div=3;
  int r[]=new int[wh];
  
  int sum,x,y,i,p,p1,p2,yp,yi,yw;
  int vmin[] = new int[max(w,h)];
  int vmax[] = new int[max(w,h)];

  yw=yi=0;

  for (y=0;y<h;y++){
    sum=0;
    for(i=-1;i<=1;i++){
      p=mapOut[yi+min(wm,max(i,0))];
      sum+= p;
    }
    for (x=0;x<w;x++){

      r[yi]=sum/div;

      if(y==0){
        vmin[x]=min(x+2,wm);
        vmax[x]=max(x-1,0);
      }
      p1=mapOut[yw+vmin[x]];
      p2=mapOut[yw+vmax[x]];

      sum+= p1 -p2 ;
      yi++;
    }
    yw+=w;
  }

  for (x=0;x<w;x++){
    sum=0;
    yp=-w;
    for(i=-1;i<=1;i++){
      yi=max(0,yp)+x;
      sum+=r[yi];

      yp+=w;
    }
    yi=x;
    for (y=0;y<h;y++){
      mapOut[yi]=sum/div;
      if(x==0){
        vmin[y]=min(y+2,hm)*w;
        vmax[y]=max(y-1,0)*w;
      }
      p1=x+vmin[y];
      p2=x+vmax[y];

      sum+=r[p1]-r[p2];

      yi+=w;
    }
  }

}