// Inversion Filter 1.0
// by Mario Klingemann
// http://incubator.quasimondo.com
// contact: mario@quasimondo.com
//
// Reuse of this code is permitted
// as long as this copyright notice
// is included.

BImage a;
int xc,yc;
int k;
boolean drag;
boolean newFrame;


void setup()
{
  drag=false;
  k=80*80;

  // Uncomment this Block if you want to use live video:
  /*
  size(320,240);
  newFrame = false;
  a=new BImage(320,240);
  beginVideo(320, 240,18); 
*/
  
  
  a=loadImage("sweden.jpg");
  size(a.width, a.height);

  noStroke();
  }

void mousePressed(){
  drag=true;
  xc=mouseX;
  yc=mouseY;
}

void mouseReleased(){
  drag=false;
}

void mouseDragged(){
  int dx= xc-mouseX;
  int dy= yc-mouseY;
  k=5*(dx*dx+dy*dy);

}

void loop()
{
  // Uncomment this Block if you want to use live video:
  /*
  if(newFrame) {
    System.arraycopy(video.pixels, 0, a.pixels, 0, video.pixels.length);
    newFrame = false;
  }
 */
 
  if (!drag){
    xc=mouseX;
    yc=mouseY;
  }
  inversion(a);
 
}

void inversion(BImage img){
  int x,y,i,d,xn,yn,dx,dy;
  boolean mx,my;
  int[] pix=img.pixels;
  i=0;
  for (y=0;y<height;y++){
    dy=y-yc;
    for (x=0;x<width;x++){
        dx=x-xc;
        d=dx*dx+dy*dy;
        if (d!=0){
         xn=xc+(k*dx)/d;
         yn=yc+(k*dy)/d;
        } else {
          xn=xc;
          yn=yc;
        }
        mx=false;
        while (xn<0){
          xn+=width;
          mx=!mx;
        }
        while (xn>=width){
          xn-=width;
          mx=!mx;
        }
        my=false;
        while (yn<0){
          yn+=height;
          my=!my;
        }
        while (yn>=height){
          yn-= height;
          my=!my;
        }
        if (mx){
          xn=width-1-xn;
        }
        if (my){
          yn=height-1-yn;
        }
        pixels[i++]=pix[xn+yn*width];
     }
  }
}

// Uncomment this function for live Video:
/*
void videoEvent(){
  newFrame = true;
}
*/